{-# LANGUAGE OverloadedStrings #-}

module HSWasm where

import qualified Data.ByteString.Char8         as B
import qualified Data.ByteString.Unsafe        as BU
import           Data.String

import           Foreign.C.String
import           Foreign.C.Types
import           Foreign.Marshal.Array
import           Foreign.Ptr

foreign import ccall unsafe "global_object"
  hs_global_object :: IO Int

foreign import ccall unsafe "float_val"
  hs_float_val :: Double -> IO Int

foreign import ccall unsafe "js_float"
  hs_js_float :: Int -> IO Double

foreign import ccall unsafe "int_val"
  hs_int_val :: Int -> IO Int

foreign import ccall unsafe "js_int"
  hs_js_int :: Int -> IO Int

foreign import ccall unsafe "string_val"
  hs_string_val :: CString -> Int -> IO Int

foreign import ccall unsafe "js_string"
  hs_js_string :: Int -> IO CString

foreign import ccall unsafe "prop"
  hs_prop :: Int -> CString -> Int -> IO Int

foreign import ccall unsafe "invoke"
  hs_invoke :: Int -> Ptr Int -> Int -> IO Int

foreign import ccall unsafe "call"
  hs_call :: Int -> CString -> Int -> Ptr Int -> Int -> IO Int

foreign import ccall unsafe "set"
  hs_set :: Int -> CString -> Int -> Int -> IO ()

foreign import ccall unsafe "await"
  hs_await :: Int -> IO Int

data JSVal = JSObject Int | JSStr B.ByteString | JSInt Int | JSFloat Double | JSBool Bool deriving (Eq)

instance IsString JSVal where
  fromString = JSStr . B.pack

valueGet :: JSVal -> IO JSVal
valueGet (JSObject n) = pure $ JSObject n
valueGet (JSStr    s) = do
  i <- BU.unsafeUseAsCStringLen s $ \(saddr, len) -> hs_string_val saddr len
  pure (JSObject i)
valueGet (JSFloat n    ) = hs_float_val n >>= pure . JSObject
valueGet (JSInt   n    ) = hs_int_val n >>= pure . JSObject
valueGet (JSBool  True ) = pure valTrue
valueGet (JSBool  False) = pure valFalse

fromJSObject :: JSVal -> Int
fromJSObject (JSObject n) = n


valUndefined = JSObject 0
valNaN = JSObject 1
valZero = JSObject 2
valNull = JSObject 3
valTrue = JSObject 4
valFalse = JSObject 5
valGlobal = JSObject 6
valHaskell = JSObject 7
globalThis = valGlobal


jsFloat :: JSVal -> IO Double
jsFloat (JSObject oid) = hs_js_float oid


jsInt :: JSVal -> IO Int
jsInt (JSObject oid) = hs_js_int oid


jsString :: JSVal -> IO B.ByteString
jsString (JSObject oid) = hs_js_string oid >>= B.packCString


jsBool :: JSVal -> IO Bool
jsBool v | v == valTrue  = pure True
         | v == valFalse = pure False


prop :: JSVal -> B.ByteString -> IO JSVal
prop (JSObject parentid) name = do
  i <- BU.unsafeUseAsCStringLen name
    $ \(saddr, len) -> hs_prop parentid saddr len
  pure (JSObject i)


invoke :: JSVal -> [JSVal] -> IO JSVal
invoke (JSObject func) args = do
  argObjs <- sequence $ map valueGet args
  let argIds = map (\(JSObject i) -> i) argObjs
  i <- withArray argIds $ \(idPtr) -> do
    hs_invoke func idPtr (fromIntegral $ length argIds)
  pure (JSObject i)


call :: JSVal -> B.ByteString -> [JSVal] -> IO JSVal
call (JSObject v) methodName args = do
  argObjs <- sequence $ map valueGet args
  let argIds = map fromJSObject argObjs
  i <- withArray argIds $ \(idPtr) -> do
    BU.unsafeUseAsCStringLen methodName
      $ \(mp, mlen) -> hs_call v mp mlen idPtr (fromIntegral $ length argIds)
  pure (JSObject i)

set :: JSVal -> B.ByteString -> JSVal -> IO ()
set (JSObject v) b x = do
  xval <- valueGet x
  BU.unsafeUseAsCStringLen b $ \(p, plen) -> hs_set v p plen (fromJSObject xval)
